net-im/schildichat-desktop-bin/schildichat-desktop-bin: bump to 1.9.0-sc.1

Signed-off-by: Balazs Toldi <balazs@toldi.eu>

net-im/schildichat-desktop-bin/schildichat-desktop-bin-1.9.0-r1.ebuild

@@ -0,0 +1,81 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit unpacker xdg
+
+MY_PN="schildichat-desktop"
+MY_PVR="$(echo ${PVR//r/sc.})"
+
+DESCRIPTION="SchildiChat is a Matrix client based on Element with a more traditional instant messaging experience."
+HOMEPAGE="https://schildi.chat/"
+SRC_URI="https://github.com/SchildiChat/schildichat-desktop/releases/download/v${MY_PVR}/${MY_PN}_${MY_PVR}_amd64.deb"
+S="${WORKDIR}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64"
+IUSE="+emoji"
+
+RDEPEND="app-accessibility/at-spi2-atk:2
+	app-crypt/libsecret
+	dev-db/sqlcipher
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libXScrnSaver
+	x11-libs/pango
+	emoji? ( media-fonts/noto-emoji )"
+DEPEND="${RDEPEND}"
+
+QA_PREBUILT="
+	/opt/SchildiChat/chrome-sandbox
+	/opt/SchildiChat/schildichat-desktop
+	/opt/SchildiChat/libEGL.so
+	/opt/SchildiChat/libGLESv2.so
+	/opt/SchildiChat/libffmpeg.so
+	/opt/SchildiChat/libvk_swiftshader.so
+	/opt/SchildiChat/libvulkan.so.1
+	/opt/SchildiChat/swiftshader/libEGL.so
+	/opt/SchildiChat/swiftshader/libGLESv2.so"
+
+src_prepare() {
+	default
+	rm opt/SchildiChat/{LICENSE.electron.txt,LICENSES.chromium.html} || die
+}
+
+src_install() {
+	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	insinto /
+	doins -r usr
+	doins -r opt
+	local f
+	for f in ${QA_PREBUILT}; do
+		fperms +x "${f}"
+	done
+	fperms u+s /opt/SchildiChat/chrome-sandbox
+
+	dosym ../../opt/SchildiChat/${MY_PN} /usr/bin/${MY_PN}
+}